Інколи виникає необхідність змінити якесь значення (наприклад, назву землевласника, назву суміжного землекористувача, назву вулиці тощо) зразу у багатьох файлах. Цей скрипт зробить це за вас.

Після запуску появиться вікно, де треба ввести текст, який потрібно замінити у файлах

Потім текст, на який треба замінити

І виберіть папку, де знаходяться обмінники

В результаті отримаємо повідомлення про результат:

І в результаті у папці з обмінниками буде створена нова папка Оброблені файли, де будуть збережені тільки ті файли, у яких було знайдено та замінено відповідне значення.

При цьому зверніть увагу, що заміну скриптом можна проводити тільки по значеннях, які заключені в один спільний кінцевий тег. Якщо це, наприклад, назва землевласника  (ТОВ "Зелена балка"), то можна так і вводити. Але коли це ПІБ, то спершу треба замінити прізвище, потім ім'я, а потім по батькові. Оскільки вони у файлі XML у різних тегах:
                        <LastName>Шевченко</LastName>
                        <FirstName>Ірина</FirstName>
                        <MiddleName>Ігорівна</MiddleName>

А ось власне і сам скрипт:

$Ext=.xml
$Intut=@Dialog.Ask Введіть, що треба замінити Size=300
$Intut=@ReplaceChar "*$Intut
$Output=@Dialog.Ask Введіть, на що це треба замінити Size=300
$Output=@ReplaceChar "*$Output
$InF=@Dialog.SelectFolder Вкажіть папку з файлами
@If $InF= @Break
@Text.FolderList *$Ext $InF
$C=@Text.Count
@If $C=0 @Break В папці "$InF" відсутні файли $Ext
$LastF=@ExtractFileFolder $InF
$OutF=$InF
@if "$LastF"<>"Оброблені файли" then $OutF=$InF\Оброблені файли
@if "$LastF"<>"Оброблені файли" then @CreateFolder $OutF
@if "$LastF"<>"Оброблені файли" then @CleanFolder $OutF
@Progress.Start $C Роблю... (всього $C файлів)
$I=0
$R=0
%Start
$I=$I+1
@Progress.StepBy 1
@If $I>$C then @Progress.Stop
@If $I>$C then @Run $OutF
@If $I>$C then @Break Заміна проведена у $R файлах із $C! Оброблені файли збережено у папці $OutF
$InF=@Text.Line[$I]
@Text[1].Load $InF
$Text=@Text[1].Text
$Text=@ReplaceChar "*$Text
$Text=@Calc replace("$Text","$Intut","$Output",0,1)
$Text=@DequoteText $Text
$Pos=@Calc Pos("$Output","$Text")
@if $Pos>0 then $R=$R+1
@if $Pos=0 then @Goto %Start
$Text=@ReplaceChar *"$Text
@Text[1].Text $Text
$InF=@ExtractFileName $InF
@Text[1].Save $OutF\$InF
$Progress=@Progress.Canceled
@if $Progress=1 then @Break Перервано! Оброблено $I файлів із $C.||Заміна проведена у $R файлах! Оброблені файли збережено у папці $OutF
@Goto %Start

Підказка: якщо у ваших файлах заповнено усе по-різному, або взагалі не заповнено, а ви хочете заповнити усе зразу однаковим значенням, то тоді при заміні вказуйте не значення, а сам тег. Наприклад:

</ProprietorCode>

замінити на:

22</ProprietorCode>

При цьому важливо, щоб теги (чи декілька тегів в купі) були оригінальні, тобто, щоб більше ніде не повторювалися по тексту.